From a780240bdac5db4df0310f0765b756cc6fb7d93e Mon Sep 17 00:00:00 2001
From: turret <turret@duck.com>
Date: Fri, 8 Dec 2023 21:49:35 -0600
Subject: dev-libs/girara: add 0.4.1

for dev-libs/zathura-0.5.3
---
 dev-libs/girara/Manifest            |  1 +
 dev-libs/girara/girara-0.4.1.ebuild | 59 +++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 dev-libs/girara/Manifest
 create mode 100644 dev-libs/girara/girara-0.4.1.ebuild

(limited to 'dev-libs/girara')

diff --git a/dev-libs/girara/Manifest b/dev-libs/girara/Manifest
new file mode 100644
index 0000000..5ef5ba8
--- /dev/null
+++ b/dev-libs/girara/Manifest
@@ -0,0 +1 @@
+DIST girara-0.4.1.tar.xz 61320 BLAKE2B c0320dd2d1cf58654b56a5e61fe73d08a991754fcdcd70aded7dfc6fa1e8c52a0889a798e3a47957a8fef055df0470a8d3952c6d6b55b18d54c965e79662a0f8 SHA512 0d0ea107d50cf0104d5b92f8fa0b2fb22b2ba884d10d001089e0570e08adcbe550be208eec3ff0f7ba0e13714a387de025e8a950e4bc2431a9581f4ee4ebbc98
diff --git a/dev-libs/girara/girara-0.4.1.ebuild b/dev-libs/girara/girara-0.4.1.ebuild
new file mode 100644
index 0000000..6ef1dcc
--- /dev/null
+++ b/dev-libs/girara/girara-0.4.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson virtualx
+
+DESCRIPTION="UI library that focuses on simplicity and minimalism"
+HOMEPAGE="https://pwmt.org/projects/girara/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://pwmt.org/projects/girara/download/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+fi
+
+LICENSE="ZLIB"
+SLOT="0"
+IUSE="doc libnotify test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-accessibility/at-spi2-core
+	dev-libs/glib:2
+	dev-libs/json-glib:=
+	media-libs/harfbuzz:=
+	x11-libs/cairo[glib]
+	x11-libs/gdk-pixbuf
+	>=x11-libs/gtk+-3.20:3
+	x11-libs/pango
+	libnotify? ( x11-libs/libnotify )
+"
+RDEPEND="${DEPEND}"
+# Tests are run under virtx
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-libs/check
+		x11-libs/gtk+:3[X]
+	)
+"
+
+src_configure() {
+	local -a emesonargs=(
+		-Djson=enabled
+		$(meson_feature doc docs)
+		$(meson_feature libnotify notify)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# TODO: run test on wayland
+	virtx meson_src_test
+}
-- 
cgit v1.2.3