From 0c47825062afccbaee13ae9e90094fe9d2bedc6a Mon Sep 17 00:00:00 2001
From: turret <turret@duck.com>
Date: Fri, 30 Jun 2023 18:56:12 -0500
Subject: media-gfx/donut-4: version bump

---
 media-gfx/donut/donut-4.ebuild | 44 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 media-gfx/donut/donut-4.ebuild

(limited to 'media-gfx/donut/donut-4.ebuild')

diff --git a/media-gfx/donut/donut-4.ebuild b/media-gfx/donut/donut-4.ebuild
new file mode 100644
index 0000000..783a5c5
--- /dev/null
+++ b/media-gfx/donut/donut-4.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="spinning X11 donut"
+HOMEPAGE="https://git.turret.cyou/progs/donut.git/about/"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.turret.cyou/progs/donut.git"
+else
+	SRC_URI="https://git.turret.cyou/progs/donut.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+RESTRICT="mirror"
+DEPEND="x11-libs/libX11"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/ -Os//" \
+		-e "/^\(LDFLAGS\|CFLAGS\|CPPFLAGS\)/{s| = | += |g;s|-s ||g}" \
+		config.mk || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	emake CC=$(tc-getCC) donut
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	save_config config.h
+}
-- 
cgit v1.2.3